sitegen = require "sitegen"
Site = require "sitegen.site"
Path = require "sitegen.path"
html = require "sitegen.html"
date = require "date"

import tag from html
import escape_patt from require "sitegen.common"
import p from require "moon"

-- Change output dir to what Openresty prefers
Site.config.out_dir = "html/"

-- Deactivate "pygments" plugin because it conflicts with pandoc highlighting
Site.default_plugins = for v in *Site.default_plugins
  if v\find "pygments" then continue else v

-- Remove default markdown renderer
Site.default_renderers = for v in *Site.default_renderers
  if v\find "markdown" then continue else v

-- Add pandoc markdown renderer
rend = "renderers.markdown"
require(rend).cmd = "pandoc --mathjax >"
table.insert Site.default_renderers, rend

-- https://github.com/leafo/sitegen/blob/v0.2/spec/sitegen_spec.moon#L9-L18
get_files = (path, prefix=path) ->
  files = Path.read_exec "find", path, "-type", "f"
  files = [f for f in files\gmatch "[^\n]+"]

  if prefix
    files = for file in *files
      file\gsub "^#{escape_patt prefix}/?", ""

  table.sort files
  files

rootname = (str) ->
  result = string.gsub str, "%..+", ""
  result

-- TODO use split function from common
split = (str, delimiter="/") ->
  [capture for capture in str\gmatch "[^#{delimiter}]+"]

last = (list) -> list[#list]
join = (first, last, delimiter="/") -> table.concat { first, last }, delimiter
reverse = (list={}) -> [item for item in *list[#list, 1, -1]]
target = (path, prefix) -> join prefix, rootname(last(split path))

posts = (path=".") ->
  files = reverse get_files path
  {join(path, file), target(file, "/posts") for file in *files}

extract_id = (source) -> string.match Path.filename(source), "%a[%w%-]+"
extract_date = (source) -> string.match Path.filename(source), "%d+%-%d%d%-%d%d"
format_date = (str) -> date(str)\fmt "%b %d, %Y"
publish_date = (path) -> format_date extract_date path

common = require("sitegen.common")
h = (word) -> word\sub(1, 1)\upper!
t = (word) -> word\sub(2, -1)\lower!
titleize = (word) -> h(word), t(word)

titleize_slug = (slug) ->
  words = [{ titleize word } for word in *common.split slug, "-"]
  [head .. tail for { head, tail } in *words]

list_posts = (page, limit) ->
  posts = page.site\query_pages { is_a: "post" }
  table.sort posts, (a, b) -> a.source > b.source

  html.build ->
    import section, h3, a, time from tag

    [section {
      h3 { a { href: meta.target .. ".html", meta.title or titleize_slug meta.id }}
      time { publish_date source }
      { "—", if meta.blurb then html.builders.text! meta.blurb }
      a { class: "read-post-link", href: meta.target .. ".html",
        "Read post →"
      }
    } for { meta: meta, source: source } in *posts[1, limit or #posts]]

sitegen.create =>
  @site_title = "WebDevCat.me · Catalin Mititiuc"
  @app_name = "stasis"
  @version = "0.2.12"
  @list_posts = list_posts

  add "index.html"
  add "blog.html", target: "posts/index", template: "blog"

  for path, target in pairs posts "docs"
    add path,
      target: target
      template: "post"
      is_a: "post"
      publish_date: publish_date(path)
      id: extract_id(path)
      titleize: (slug) -> html.build -> titleize_slug(slug)

  -- replace post markdown yaml headers with moonscript headers
  filter "docs", (body) =>
    body\gsub "^%-%-%-.-%.%.%.", (yaml_header) ->
      header = yaml_header\gsub "%-%-%-", "{"
      moonscript_header = header\gsub "%.%.%.", "}"
      moonscript_header

  copy "app.css"