sitegen = require "sitegen"
Site = require "sitegen.site"
Path = require "sitegen.path"
html = require "sitegen.html"
common = require "sitegen.common"
cosmo = require "sitegen.cosmo"
date = require "date"

html_renderer = require "sitegen.renderers.html"
import tag from html
import escape_patt from require "sitegen.common"
import p from require "moon" -- debug

-- Change output dir to what Openresty prefers
Site.config.out_dir = "html/"

-- Configure the command our custom renderer uses to convert markdown to html
rend = "renderers.markdown"
require(rend).cmd = "pandoc --mathjax >"

-- Replace the default markdown renderer with our custom renderer
Site.default_renderers = for v in *Site.default_renderers
  if v\find "markdown" then rend else v

-- Remove "pygments" plugin because it conflicts with pandoc syntax highlighting
Site.default_plugins = for v in *Site.default_plugins
  if v\find "pygments" then continue else v

-- from https://github.com/leafo/sitegen/blob/v0.2/spec/sitegen_spec.moon#L9-L18
get_files = (path, prefix=path) ->
  files = Path.read_exec "find", path, "-type", "f"
  files = [f for f in files\gmatch "[^\n]+"]

  if prefix
    files = for file in *files
      file\gsub "^#{escape_patt prefix}/?", ""

  table.sort files
  files

-- strip file extension from filename
rootname = (str) ->
  result = string.gsub str, "%..+", ""
  result

last = (list) -> list[#list]
join = (first, last, delimiter="/") -> table.concat { first, last }, delimiter
reverse = (list={}) -> [item for item in *list[#list, 1, -1]]
target = (path, prefix) -> join prefix, rootname(last(common.split path, "/"))

extract_id = (source) -> string.match Path.filename(source), "%a[%w%-]+"
extract_date = (source) -> string.match Path.filename(source), "%d+%-%d%d%-%d%d"
format_date = (str) -> date(str)\fmt "%b %d, %Y"
publish_date = (path) -> format_date extract_date path

h = (word) -> word\sub(1, 1)\upper!
t = (word) -> word\sub(2, -1)\lower!
titleize = (word) -> h(word), t(word)

titleize_slug = (slug="") ->
  words = [{ titleize word } for word in *common.split slug, "-"]
  table.concat [head .. tail for { head, tail } in *words], " "

template = [[
<section>
  <h3><a href="$target">$title</a></h3>
  <time>$publish_date</time> — $blurb
  <a class="read-post-link" href="$target">Read post →</a>
</section>
]]

-- use in templates like this
--   $each{list_posts({limit = 5}), "post"}[[$post]]
-- or like this
--   $each{list_posts(), "post"}[[$post]]
list_posts = (args={}) =>
  posts = @site\query_pages { is_a: "post" }
  table.sort posts, (a, b) -> a.source > b.source

  return for page in *posts[1, args.limit or #posts]
    page.tpl_scope = page\get_tpl_scope!
    page.meta.title = page.meta.title or titleize_slug page.meta.id
    page.template_stack = common.Stack!
    page.template_stack\push @site.config.default_template
    @renderer\render page, template
    -- common.fill_ignoring_pre template,
    --   target: meta.target
    --   post_title: meta.title or titleize_slug meta.id
    --   publish_date: publish_date source
    --   blurb: meta.blurb

-- call like this from a template: $(get_posts())[[<p>$target</p>]]
-- or like this: $(get_posts({limit = 5}))[[<p>$target</p>]]
get_posts = (args={}) =>
  posts = @site\query_pages { is_a: "post" }
  table.sort posts, (a, b) -> a.source > b.source

  return for { meta: meta, source: source } in *posts[1, args.limit or #posts]
    {
      target: meta.target
      post_title: meta.title or titleize_slug meta.id
      publish_date: publish_date source
      blurb: meta.blurb
    }

-- replace '$if' helper function with cosmo's 'cif'
html_renderer.cosmo_helpers.if = (args, has_block) => cosmo.cif args, has_block
-- add a '$titleize' helper function
html_renderer.cosmo_helpers.titleize = (slug) => titleize_slug slug

documents = (path=".") ->
  files = reverse get_files path
  {join(path, file), target(file, "/posts") for file in *files}

sitegen.create =>
  @site_title = "WebDevCat.me"
  @app_name = "stasis"
  @version = "0.2.12"
  @list_posts = list_posts
  @get_posts = get_posts

  add "index.html", title: "Catalin Mititiuc", blah: {{say: "wan"},{say: "tuu"}}
  add "blog.html", title: "Posts", target: "posts/index", template: "blog"

  -- add "about.html", some: {
  --   { one: "alpha", two: "beta" },
  --   { one: "A", two: "B" }
  -- }, cif: cosmo.cif, math: math, x: 2

  for path, target in pairs documents "docs"
    id = extract_id path

    add path,
      target: Path.join Path.basepath(target), id
      template: "post"
      is_a: "post"
      publish_date: publish_date path
      id: id

  -- replace post markdown yaml headers with moonscript headers
  filter "docs", (body) =>
    body\gsub "^%-%-%-.-%.%.%.", (yaml_header) ->
      header = yaml_header\gsub "%-%-%-", "{"
      moonscript_header = header\gsub "%.%.%.", "}"
      moonscript_header

  copy "app.css"