Path = require "sitegen.path"

needs_shell_escape = (str) -> not not str\match "[^%w_-]"
shell_escape = (str) -> str\gsub "'", "''"

_prepare_command = (cmd, ...) ->
  args = for x in *{...}
    if needs_shell_escape x then "'#{shell_escape x}'" else x

  args = table.concat args, " "
  "#{cmd} #{args}"

write_exec = (input, cmd, ...) ->
  handle = io.popen _prepare_command(cmd, ...), "w"
  with handle\write input
    handle\close!

convert = =>
  (md_source) ->
    markup_filename = os.tmpname!
    write_exec md_source, @cmd, markup_filename
    Path.read_file markup_filename

class PandocRenderer extends require "sitegen.renderers.markdown"
  unescape_cosmo = @unescape_cosmo
  escape_cosmo = @escape_cosmo
  pandoc = convert @

  cmd: "pandoc >"

  render: (page, md_source) =>
    md_source = page\pipe "renderer.markdown.pre_render", md_source
    md_source, escapes = escape_cosmo md_source

    html_source = assert pandoc md_source
    html_source = unescape_cosmo html_source, escapes

    super page, html_source