sitegen = require "sitegen"
Site = require "sitegen.site"
Path = require "sitegen.path"
html = require "sitegen.html"
common = require "sitegen.common"
cosmo = require "sitegen.cosmo"
date = require "date"

html_renderer = require "sitegen.renderers.html"
import tag from html
import escape_patt from require "sitegen.common"
import p from require "moon" -- debug

-- Change output dir to what Openresty prefers
Site.config.out_dir = "html/"

-- Configure the command our custom renderer uses to convert markdown to html
rend = "renderers.markdown"
require(rend).cmd = "pandoc --mathjax >"

-- Replace the default markdown renderer with our custom renderer
Site.default_renderers = for v in *Site.default_renderers
  if v\find "markdown" then rend else v

-- Remove "pygments" plugin because it conflicts with pandoc syntax highlighting
Site.default_plugins = for v in *Site.default_plugins
  if v\find "pygments" then continue else v

-- from https://github.com/leafo/sitegen/blob/v0.2/spec/sitegen_spec.moon#L9-L18
get_files = (path, prefix=path) ->
  files = Path.read_exec "find", path, "-type", "f"
  files = [f for f in files\gmatch "[^\n]+"]

  if prefix
    files = for file in *files
      file\gsub "^#{escape_patt prefix}/?", ""

  table.sort files
  files

-- strip file extension from filename
rootname = (str) ->
  result = string.gsub str, "%..+", ""
  result

extract_id = (source) -> string.match Path.filename(source), "%a[%w%-]+"
extract_date = (source) -> string.match Path.filename(source), "%d+%-%d%d%-%d%d"
format_date = (str) -> date(str)\fmt "%b %d, %Y"
publish_date = (path) -> format_date extract_date path

last = (list) -> list[#list]
join = (first, last, delimiter="/") -> table.concat { first, last }, delimiter
reverse = (list={}) -> [item for item in *list[#list, 1, -1]]
target = (path, prefix=".") ->

  a = rootname(last(common.split path, "/"))
  b = a\gsub "#{escape_patt(extract_date(a) .. "-")}/?", ""
  p b
  b
  Path.join prefix, a\gsub("#{escape_patt(extract_date(a) .. "-")}/?", "")

h = (word) -> word\sub(1, 1)\upper!
t = (word) -> word\sub(2, -1)\lower!
titleize = (word) -> h(word), t(word)

titleize_slug = (slug="") ->
  words = [{ titleize word } for word in *common.split slug, "-"]
  table.concat [head .. tail for { head, tail } in *words], " "

template = [[
<section>
  <h3><a href="$url">$title</a></h3>
  <time>$publish_date</time> — $blurb
  <a class="read-post-link" href="$url">Read post →</a>
</section>
]]

-- setup in create function:
--
-- sitegen.create =>
--   @list_posts = list_posts @, [template]
--
-- use in templates:
--
-- `list_posts @` expects $(list_posts({limit = 2}))[[<p>$title</p>]]
-- `list_posts @, template` expects $each{list_posts({limit = 2}), "post"}[[$post]]
list_posts = (template) => (args={}) =>
  pages = @site\query_pages { is_a: "post" }
  table.sort pages, (a, b) -> a.source > b.source
  limit = math.min args.limit or #pages, #pages

  return for page in *pages[1, limit]
    { title: title, id: id, publish_date: date, blurb: blurb } = page.meta

    vals = {
      title: title or titleize_slug id
      publish_date: date
      blurb: blurb
      url: rootname page\url_for!
    }

    if template then common.fill_ignoring_pre template, vals else vals

-- replace '$if' helper function with cosmo's 'cif'
html_renderer.cosmo_helpers.if = (args, has_block) => cosmo.cif args, has_block
-- add a '$titleize' helper function
html_renderer.cosmo_helpers.titleize = (slug) => titleize_slug slug

documents = (path=".") ->
  files = reverse get_files path
  {join(path, file), target(file, "/posts") for file in *files}

clean = (target) ->
  target\gsub "#{escape_patt(extract_date(target) .. "-")}/?", ""

sitegen.create =>
  @site_title = "WebDevCat.me"
  @app_name = "stasis"
  @version = "0.2.12"
  @list_posts = list_posts @, template

  add_all = (name, files) ->
    for path, _ in pairs files
      id = extract_id path

      add path,
        target: clean(target(path, "/posts"))
        template: name
        is_a: name
        publish_date: publish_date path
        id: id

  add "index.html", title: "Catalin Mititiuc"
  add "blog.html", title: "Posts", target: "posts/index", template: "blog"
  add_all "post", documents "docs"

  -- replace post markdown yaml headers with moonscript headers
  filter "docs", (body) =>
    body\gsub "^%-%-%-.-%.%.%.", (yaml_header) ->
      header = yaml_header\gsub "%-%-%-", "{"
      moonscript_header = header\gsub "%.%.%.", "}"
      moonscript_header

  copy "app.css"